एक्सेल में उम्र की गणना कैसे करें: जन्म तिथि से, दो तिथियों के बीच

ट्यूटोरियल एक्सेल में जन्मदिन से उम्र प्राप्त करने के विभिन्न तरीके दिखाता है। आज की तिथि या किसी विशेष तिथि पर वर्षों, महीनों और दिनों में सटीक आयु प्राप्त करने के लिए, आप पूर्ण वर्षों की संख्या के रूप में आयु की गणना करने के लिए कुछ सूत्र सीखेंगे।

एक्सेल में उम्र की गणना करने के लिए कोई विशेष कार्य नहीं है, हालांकि जन्म तिथि को उम्र में बदलने के कुछ अलग तरीके मौजूद हैं। यह ट्यूटोरियल प्रत्येक तरीके के फायदे और कमियों की व्याख्या करेगा, यह दिखाएगा कि एक्सेल में एक आदर्श आयु गणना फॉर्मूला कैसे बनाया जाए और कुछ विशिष्ट कार्यों को हल करने के लिए इसे ट्वीक किया जाए।

  • एक्सेल में जन्म तिथि से आयु की गणना कैसे करें
    • आयु की गणना पूर्ण वर्षों की संख्या के रूप में करें
    • जन्म तिथि से वर्ष, महीनों और दिनों में आयु प्राप्त करें
  • एक्सेल में आयु सूत्र के और उदाहरण
    • किसी विशिष्ट तिथि पर आयु की गणना करें
    • एक निश्चित वर्ष में आयु प्राप्त करें
    • गणना करें जब कोई व्यक्ति N वर्ष की आयु प्राप्त करता है
    • विभिन्न कोशिकाओं में दिन, महीने और वर्ष से आयु प्राप्त करें
  • एक्सेल में आयु कैलकुलेटर
    • एक्सेल में आयु कैलकुलेटर कैसे बनाएं
    • एक्सेल के लिए उपयोग में आसान आयु कैलकुलेटर
  • किसी विशेष आयु से कम या अधिक आयु को हाइलाइट करें

एक्सेल में जन्म तिथि से आयु की गणना कैसे करें

रोजमर्रा की जिंदगी में, सवाल “आप कितने साल के हैं?” आमतौर पर एक उत्तर का अर्थ होता है जो दर्शाता है कि आप कितने साल जीवित हैं। Microsoft Excel में, आप सटीक आयु की गणना महीनों, दिनों, घंटों और यहां तक कि मिनटों में करने के लिए एक सूत्र बना सकते हैं। लेकिन आइए पारंपरिक बनें, और पहले वर्षों में जन्मतिथि से आयु की गणना करना सीखें।

साल में उम्र के लिए बेसिक एक्सेल फॉर्मूला

आप आम तौर पर किसी की उम्र का पता कैसे लगाते हैं? बस जन्म तिथि को वर्तमान तिथि से घटाकर। इस पारंपरिक आयु सूत्र का उपयोग एक्सेल में भी किया जा सकता है।

मान लें कि जन्मतिथि सेल बी 2 में है, वर्षों में आयु की गणना करने का सूत्र इस प्रकार है

=(TODAY()-B2)/365

सूत्र का पहला भाग (TODAY()-B2) वर्तमान तिथि और जन्म तिथि के बीच का अंतर देता है, और फिर आप वर्षों की संख्या प्राप्त करने के लिए उस संख्या को 365 से विभाजित करते हैं।

सूत्र स्पष्ट और याद रखने में आसान है, हालांकि, एक छोटी सी समस्या है। ज्यादातर मामलों में, यह एक दशमलव संख्या देता है जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है

Age calculation formula that returns decimal numbers

पूर्ण वर्षों की संख्या प्रदर्शित करने के लिए, दशमलव को निकटतम पूर्णांक तक गोल करने के लिए INT फ़ंक्शन का उपयोग करें:

=INT((TODAY()-B2)/365)

Using the basic age calculation formula in Excel

कमियां: एक्सेल में इस उम्र के फार्मूले का उपयोग करने से बहुत सटीक परिणाम मिलते हैं, लेकिन दोषरहित नहीं। एक वर्ष में दिनों की औसत संख्या से भाग देने पर अधिकांश समय ठीक रहता है, लेकिन कभी-कभी यह उम्र गलत हो जाती है। उदाहरण के लिए, यदि किसी का जन्म 29 फरवरी को हुआ है और आज 28 फरवरी है, तो सूत्र व्यक्ति को एक दिन बड़ा कर देगा।

एक विकल्प के रूप में, आप 365 के बजाय 365.25 से विभाजित कर सकते हैं क्योंकि हर चौथे वर्ष में 366 दिन होते हैं। हालाँकि, यह दृष्टिकोण भी सही नहीं है। उदाहरण के लिए, यदि आप किसी ऐसे बच्चे की आयु की गणना कर रहे हैं जो अभी तक एक लीप वर्ष में नहीं रहा है, तो 365.25 से विभाजित करने पर गलत परिणाम मिलता है।

कुल मिलाकर, वर्तमान तिथि से जन्म तिथि घटाना सामान्य जीवन में बहुत अच्छा काम करता है, लेकिन एक्सेल में आदर्श दृष्टिकोण नहीं है। आगे इस ट्यूटोरियल में, आप कुछ विशेष कार्यों के बारे में जानेंगे जो वर्ष की परवाह किए बिना त्रुटिपूर्ण रूप से आयु की गणना करते हैं।

YEARFRAC फ़ंक्शन के साथ जन्म तिथि से आयु की गणना करें

एक्सेल में DOB को उम्र में बदलने का एक अधिक विश्वसनीय तरीका YEARFRAC फ़ंक्शन का उपयोग करना है जो वर्ष का अंश देता है, अर्थात दो तिथियों के बीच पूरे दिनों की संख्या।

YEARFRAC फ़ंक्शन का सिंटैक्स इस प्रकार है:

YEARFRAC(start_date, end_date, [आधार])
पहले दो तर्क स्पष्ट हैं और शायद ही किसी अतिरिक्त स्पष्टीकरण की आवश्यकता है। आधार एक वैकल्पिक तर्क है जो उपयोग करने के लिए दिन की गणना के आधार को परिभाषित करता है।

पूरी तरह से सही आयु सूत्र बनाने के लिए, YEARFRAC फ़ंक्शन को निम्नलिखित मान प्रदान करें:

प्रारंभ_तिथि – जन्म तिथि।
End_date – TODAY() आज की तारीख को वापस करने के लिए कार्य करता है।
आधार – आधार 1 का उपयोग करें जो एक्सेल को प्रति माह दिनों की वास्तविक संख्या को प्रति वर्ष दिनों की वास्तविक संख्या से विभाजित करने के लिए कहता है।
उपरोक्त को ध्यान में रखते हुए, जन्म तिथि से आयु की गणना करने के लिए एक एक्सेल फॉर्मूला इस प्रकार है:

वर्ष (जन्म तिथि, आज (), 1)
यह मानते हुए कि जन्मतिथि सेल B2 में है, सूत्र निम्नलिखित आकार लेता है:

The YEARFRAC formula to convert DOB to age

पिछले उदाहरण की तरह, YEARFRAC फ़ंक्शन का परिणाम भी एक दशमलव संख्या है। इसे ठीक करने के लिए, अंतिम तर्क में 0 के साथ राउंडडाउन फ़ंक्शन का उपयोग करें क्योंकि आप कोई दशमलव स्थान नहीं चाहते हैं।

तो, यहाँ एक्सेल में उम्र की गणना करने के लिए एक बेहतर YEARFRAC फॉर्मूला है:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

An improved YEARFRAC formula to calculate age in years

DATEDIF के साथ Excel में आयु की गणना करें

एक्सेल में जन्म तिथि को उम्र में बदलने का एक और तरीका DATEDIF फ़ंक्शन का उपयोग करना है:

DATEDIF(start_date, end_date, unit)

यह फ़ंक्शन दो तिथियों के बीच के अंतर को विभिन्न समय इकाइयों जैसे वर्षों, महीनों और दिनों में लौटा सकता है, जो आपके द्वारा इकाई तर्क में दिए गए मूल्य पर निर्भर करता है:

  • Y – प्रारंभ और समाप्ति तिथियों के बीच पूर्ण वर्षों की संख्या देता है।
  • एम – तिथियों के बीच पूर्ण महीनों की संख्या देता है।
  • डी – दो तिथियों के बीच दिनों की संख्या देता है।
  • वाईएम – दिनों और वर्षों की अनदेखी करते हुए महीनों को लौटाता है।
  • एमडी – महीनों और वर्षों को अनदेखा करते हुए दिनों में अंतर लौटाता है।
  • YD – वर्षों को अनदेखा करते हुए, दिनों में अंतर लौटाता है।

चूंकि हम वर्षों में आयु की गणना करने का लक्ष्य रखते हैं, इसलिए हम “y” इकाई का उपयोग कर रहे हैं:

DATEDIF(date of birth, TODAY(), "y")

इस उदाहरण में, जन्म तिथि कक्ष B2 में है, और आप इस कक्ष को अपने आयु सूत्र में संदर्भित करते हैं:

=DATEDIF(B2, TODAY(), "y")

इस मामले में कोई अतिरिक्त राउंडिंग फ़ंक्शन की आवश्यकता नहीं है क्योंकि “y” इकाई के साथ एक DATEDIF सूत्र पूर्ण वर्षों की संख्या की गणना करता है:

जन्मदिन से उम्र साल, महीने और दिन में कैसे निकाले?

जैसा कि आपने अभी देखा, उम्र की गणना उस व्यक्ति के पूरे वर्षों की संख्या के रूप में करना आसान है, लेकिन यह हमेशा पर्याप्त नहीं होता है। यदि आप सही उम्र जानना चाहते हैं, यानी किसी की जन्म तिथि और वर्तमान तिथि के बीच कितने वर्ष, महीने और दिन हैं, तो 3 अलग-अलग DATEDIF फ़ंक्शन लिखें:

  • वर्षों की संख्या प्राप्त करने के लिए:=DATEDIF(B2, TODAY(), “Y”)
  • महीनों की संख्या प्राप्त करने के लिए=DATEDIF(B2, TODAY(), “YM”)
  • दिनों की संख्या प्राप्त करने के लिए=DATEDIF(B2,TODAY(),"MD")

जहाँ B2 जन्म तिथि है।

और फिर, उपरोक्त कार्यों को एक सूत्र में इस तरह संयोजित करें:=DATEDIF(B2,TODAY(),”Y”) & DATEDIF(B2,TODAY(),”YM”) & DATEDIF(B2,TODAY(),”MD”)

जैसा कि नीचे स्क्रीनशॉट में दिखाया गया है, उपरोक्त सूत्र एक टेक्स्ट स्ट्रिंग में संयोजित 3 नंबर (वर्ष, महीने और दिन) देता है:

ज्यादा समझ में नहीं आता, उह? परिणामों को अधिक सार्थक बनाने के लिए, संख्याओं को अल्पविराम से अलग करें और परिभाषित करें कि प्रत्येक मान का क्या अर्थ है:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

सूत्र बहुत अच्छा काम करता है, लेकिन आप शून्य मान छिपाकर इसे और भी बेहतर बना सकते हैं। इसके लिए, 3 IF स्टेटमेंट जोड़ें जो 0 की जांच करते हैं, प्रत्येक DATEDIF के लिए एक:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

निम्न स्क्रीनशॉट कार्रवाई में अंतिम एक्सेल आयु सूत्र को प्रदर्शित करता है – यह वर्षों, महीनों और दिनों में आयु लौटाता है, केवल गैर-शून्य मान प्रदर्शित करता है:

युक्ति यदि आप वर्षों और महीनों में उम्र की गणना करने के लिए एक्सेल फॉर्मूला ढूंढ रहे हैं, तो उपरोक्त फॉर्मूला लें और अंतिम IF(DATEDIF ()) ब्लॉक को हटा दें जो दिनों की गणना करता है।

एक्सेल में उम्र की गणना करने के लिए विशिष्ट सूत्र

ऊपर चर्चा की गई सामान्य आयु गणना सूत्र ज्यादातर मामलों में बहुत अच्छा काम करते हैं। हालाँकि, कुछ स्थितियों में, आपको बहुत विशिष्ट चीज़ की आवश्यकता हो सकती है। बेशक, हर परिदृश्य को कवर करना संभव नहीं है, लेकिन निम्नलिखित उदाहरण आपको कुछ विचार देंगे कि आप अपने विशेष कार्य के आधार पर एक आयु सूत्र को कैसे बदल सकते हैं।

एक्सेल में किसी विशिष्ट तिथि पर आयु की गणना कैसे करें

यदि आप किसी निश्चित तिथि पर किसी की उम्र जानना चाहते हैं, तो ऊपर चर्चा की गई DATEDIF आयु सूत्र का उपयोग करें, लेकिन दूसरे तर्क में TODAY () फ़ंक्शन को विशिष्ट तिथि से बदलें।

यह मानते हुए कि जन्म तिथि B1 में है, निम्न सूत्र 1 जनवरी 2020 तक आयु लौटाएगा:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

अपने आयु सूत्र को अधिक लचीला बनाने के लिए, आप किसी सेल में दिनांक इनपुट कर सकते हैं और उस सेल को अपने सूत्र में संदर्भित कर सकते हैं:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

जहाँ B1 जन्म तिथि है, और B2 वह तिथि है जिस दिन आप आयु की गणना करना चाहते हैं।

एक निश्चित वर्ष में आयु की गणना करें

यह सूत्र उन स्थितियों में काम आता है जब गणना करने की पूरी तिथि परिभाषित नहीं होती है, और आप केवल वर्ष जानते हैं।

मान लें कि आप एक चिकित्सा डेटाबेस के साथ काम कर रहे हैं, और आपका लक्ष्य अंतिम पूर्ण चिकित्सा परीक्षण के समय रोगियों की उम्र का पता लगाना है।

यह मानते हुए कि जन्म तिथि कॉलम बी में पंक्ति 3 से शुरू होती है, और अंतिम चिकित्सा परीक्षा का वर्ष कॉलम सी में है, आयु गणना सूत्र इस प्रकार है:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

चूंकि चिकित्सा परीक्षा की सटीक तिथि परिभाषित नहीं है, आप DATE फ़ंक्शन का उपयोग मनमाने ढंग से दिनांक और महीने के तर्क के साथ करते हैं, उदा। दिनांक (C3, 1, 1)।

DATE फ़ंक्शन सेल B3 से वर्ष निकालता है, आपके द्वारा प्रदान किए गए महीने और दिन की संख्याओं का उपयोग करके एक पूर्ण तिथि बनाता है (इस उदाहरण में 1-जनवरी), और उस तिथि को DATEDIF को पास कर देता है। परिणामस्वरूप, आपको किसी विशेष वर्ष की 1 जनवरी तक रोगी की आयु प्राप्त हो जाती है

वह तिथि ज्ञात कीजिए जब कोई व्यक्ति N वर्ष की आयु प्राप्त करता है

मान लीजिए आपके दोस्त का जन्म 8 मार्च 1978 को हुआ था। आप कैसे जानते हैं कि वह किस तारीख को अपनी 50 वर्ष की आयु पूरी करता है? आमतौर पर, आप उस व्यक्ति की जन्मतिथि में केवल 50 वर्ष जोड़ते हैं। एक्सेल में, आप DATE फ़ंक्शन का उपयोग करके ऐसा ही करते हैं

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

जहाँ B2 जन्म तिथि है।

सूत्र में वर्षों की संख्या को हार्ड-कोडिंग करने के बजाय, आप एक निश्चित सेल का संदर्भ दे सकते हैं जहां आपके उपयोगकर्ता कितने भी वर्षों का इनपुट कर सकते हैं (नीचे स्क्रीनशॉट में F1):

विभिन्न कक्षों में दिन, माह और वर्ष से आयु की गणना करें
जब किसी जन्मतिथि को 3 अलग-अलग कोशिकाओं में विभाजित किया जाता है (जैसे वर्ष B3 में है, महीने C3 में और दिन D3 में है), तो आप इस तरह से आयु की गणना कर सकते हैं:

DATE और DATEVALUE फ़ंक्शन का उपयोग करके जन्म तिथि प्राप्त करें:

DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

जन्म तिथि से वर्ष, महीनों और दिनों में आयु की गणना करने के लिए उपरोक्त सूत्र को DATEDIF में एम्बेड करें:

=DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

एक्सेल में आयु कैलकुलेटर

यदि आप एक्सेल में अपना स्वयं का आयु कैलकुलेटर रखना चाहते हैं, तो आप नीचे बताए गए कुछ भिन्न DATEDIF फ़ार्मुलों का उपयोग करके एक बना सकते हैं। यदि आप पहिया को फिर से नहीं बनाना चाहते हैं, तो आप हमारे एक्सेल पेशेवरों द्वारा बनाए गए आयु कैलकुलेटर का उपयोग कर सकते हैं।

एक्सेल में आयु कैलकुलेटर कैसे बनाएं

अब जब आप जानते हैं कि एक्सेल में उम्र का फॉर्मूला कैसे बनाया जाता है, तो आप एक कस्टम आयु कैलकुलेटर बना सकते हैं, उदाहरण के लिए यह:

आप ऊपर जो देख रहे हैं वह एक एम्बेडेड एक्सेल ऑनलाइन शीट है, इसलिए संबंधित सेल में अपनी जन्मतिथि दर्ज करने के लिए स्वतंत्र महसूस करें, और आपको अपनी उम्र एक पल में मिल जाएगी।

सेल A3 में जन्म तिथि और आज की तारीख के आधार पर आयु की गणना करने के लिए कैलकुलेटर निम्नलिखित सूत्रों का उपयोग करता है।

  • B5 में सूत्र आयु की गणना वर्षों, महीनों और दिनों में करता है:
    • =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
  • B6 में फॉर्मूला महीनों में उम्र की गणना करता है:
    • =DATEDIF($B$3,TODAY(),”m”)
  • Formula in B7 calculates age in days:
    • =DATEDIF($B$3,TODAY(),”d”)

यदि आपके पास एक्सेल फॉर्म नियंत्रणों के साथ कुछ अनुभव है, तो आप एक विशिष्ट तिथि पर आयु की गणना करने के लिए एक विकल्प जोड़ सकते हैं, जैसा कि निम्नलिखित स्क्रीनशॉट में दिखाया गया है:

इसके लिए, कुछ विकल्प बटन जोड़ें (डेवलपर टैब> सम्मिलित करें> फॉर्म नियंत्रण> विकल्प बटन), और उन्हें किसी सेल से लिंक करें। और फिर, आज की तिथि पर या उपयोगकर्ता द्वारा निर्दिष्ट तिथि पर आयु प्राप्त करने के लिए एक IF/DATEDIF सूत्र लिखें।

सूत्र निम्नलिखित तर्क के साथ काम करता है:

  • यदि आज का दिनांक विकल्प बॉक्स चयनित है, तो लिंक किए गए कक्ष में मान 1 प्रकट होता है (इस उदाहरण में I5), और आयु सूत्र की गणना आज की तिथि के आधार पर की जाती है:
    • IF($I$5=1, DATEDIF($B$3,TODAY(),”Y”) & ” Years, ” & DATEDIF($B$3,TODAY(), “YM”) & ” Months, ” & DATEDIF($B$3, TODAY(), “MD”) & ” Days”)
  • यदि विशिष्ट तिथि विकल्प बटन का चयन किया जाता है और सेल B7 में एक तिथि दर्ज की जाती है, तो निर्दिष्ट तिथि पर आयु की गणना की जाती है:
    • IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,”Y”) & ” Years, ” & DATEDIF($B$3, $B$7,”YM”) & ” Months, ” & DATEDIF($B$3, $B$7,”MD”) & ” Days”, “”))

अंत में, उपरोक्त कार्यों को एक दूसरे में नेस्ट करें, और आपको पूर्ण आयु गणना सूत्र (B9 में) प्राप्त होगा:

=IF($I$5=1, DATEDIF($B$3, TODAY(), “Y”) & ” Years, ” & DATEDIF($B$3, TODAY(), “YM”) & ” Months, ” & DATEDIF($B$3, TODAY(), “MD”) & ” Days”, IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,”Y”) & ” Years, ” & DATEDIF($B$3, $B$7,”YM”) & ” Months, ” & DATEDIF($B$3, $B$7,”MD”) & ” Days”, “”))

B10 और B11 में सूत्र समान तर्क के साथ कार्य करते हैं। बेशक, वे बहुत सरल हैं क्योंकि वे आयु को क्रमशः पूर्ण महीनों या दिनों की संख्या के रूप में वापस करने के लिए केवल एक DATEDIF फ़ंक्शन शामिल करते हैं।

विवरण जानने के लिए, मैं आपको इस एक्सेल एज कैलकुलेटर को डाउनलोड करने और सेल B9:B11 में सूत्रों की जांच करने के लिए आमंत्रित करता हूं।

एक्सेल के लिए उपयोग में आसान आयु कैलकुलेटर

हमारे अल्टीमेट सूट के उपयोगकर्ताओं को एक्सेल में अपनी आयु कैलकुलेटर बनाने के लिए परेशान होने की जरूरत नहीं है – यह केवल कुछ क्लिक दूर है:

  • एक सेल का चयन करें जहाँ आप एक आयु सूत्र सम्मिलित करना चाहते हैं, एबलबिट्स टूल्स टैब> दिनांक और समय समूह पर जाएँ, और दिनांक और समय विज़ार्ड बटन पर क्लिक करें।
  • दिनांक और समय विज़ार्ड प्रारंभ हो जाएगा, और आप सीधे आयु टैब पर जाएंगे।
  • आयु टैब पर, आपके लिए निर्दिष्ट करने के लिए 3 चीज़ें हैं:
    • सेल संदर्भ के रूप में जन्म का डेटा या मिमी/दिन/वर्ष प्रारूप में दिनांक।
    • आज की तिथि या विशिष्ट तिथि पर आयु।
    • चुनें कि आयु की गणना दिनों, महीनों, वर्षों या सटीक आयु में करनी है या नहीं.
  • सूत्र सम्मिलित करें बटन पर क्लिक करें।

किया हुआ!

सूत्र को चयनित सेल में पल-पल डाला जाता है, और आप कॉलम के नीचे इसे कॉपी करने के लिए भरण हैंडल को डबल-क्लिक करते हैं।

जैसा कि आपने देखा होगा, हमारे एक्सेल आयु कैलकुलेटर द्वारा बनाया गया सूत्र अब तक चर्चा की गई तुलना में अधिक जटिल है, लेकिन यह “दिन” और “दिन” जैसी समय इकाइयों के एकवचन और बहुवचन को पूरा करता है।

यदि आप “0 दिन” जैसी शून्य इकाइयों से छुटकारा पाना चाहते हैं, तो शून्य इकाइयां न दिखाएं चेक बॉक्स का चयन करें:

यदि आप इस आयु कैलकुलेटर का परीक्षण करने के साथ-साथ एक्सेल के लिए 60 और समय बचाने वाले ऐड-इन्स की खोज करने के लिए उत्सुक हैं, तो हमारे अल्टीमेट सूट का एक परीक्षण संस्करण डाउनलोड करने के लिए आपका स्वागत है। यदि आप उपकरण पसंद करते हैं और लाइसेंस प्राप्त करने का निर्णय लेते हैं, तो हमारे ब्लॉग पाठकों के लिए इस विशेष पेशकश को देखने से न चूकें।

कुछ निश्चित आयु (किसी विशिष्ट आयु से कम या अधिक) को कैसे हाइलाइट करें
कुछ स्थितियों में, आपको न केवल एक्सेल में उम्र की गणना करने की आवश्यकता हो सकती है, बल्कि उन कोशिकाओं को भी हाइलाइट करना होगा जिनमें उम्र एक विशेष आयु से कम या उससे अधिक है।

यदि आपका आयु गणना फ़ॉर्मूला पूरे वर्षों की संख्या लौटाता है, तो आप इन जैसे सरल फ़ॉर्मूला के आधार पर एक नियमित सशर्त स्वरूपण नियम बना सकते हैं:

  • 18 के बराबर या उससे अधिक आयु को हाइलाइट करने के लिए: =$C2>=18
  • To highlight ages under 18: =$C2<18

जहां C2 आयु कॉलम में सबसे ऊपर वाला सेल है (कॉलम हेडर को शामिल नहीं)।

लेकिन क्या होगा यदि आपका सूत्र वर्षों और महीनों में, या वर्षों, महीनों और दिनों में आयु प्रदर्शित करता है? इस मामले में, आपको एक DATEDIF फॉर्मूले के आधार पर एक नियम बनाना होगा जो जन्म की तारीख से वर्षों में आयु की गणना करता है।

मान लीजिए कि जन्मतिथि कॉलम बी में पंक्ति 2 से शुरू होती है, सूत्र इस प्रकार हैं:

  • To highlight ages under 18 (yellow):=DATEDIF($B2, TODAY(),"Y")<18
  • To highlight ages between 18 and 65 (green):=AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
  • To highlight ages over 65 (blue):=DATEDIF($B2, TODAY(),"Y")>65

उपरोक्त सूत्रों के आधार पर नियम बनाने के लिए, उन कक्षों या संपूर्ण पंक्तियों का चयन करें जिन्हें आप हाइलाइट करना चाहते हैं, होम टैब > शैलियाँ समूह पर जाएँ, और सशर्त स्वरूपण > नया नियम… > यह निर्धारित करने के लिए कि कौन से कक्षों को प्रारूपित करना है, एक सूत्र का उपयोग करें पर क्लिक करें।

विस्तृत चरण यहां देखे जा सकते हैं: सूत्र के आधार पर सशर्त स्वरूपण नियम कैसे बनाएं।

इस प्रकार आप एक्सेल में उम्र की गणना करते हैं। मुझे आशा है कि सूत्र आपके लिए सीखने में आसान थे और आप उन्हें अपने कार्यपत्रकों में आजमाएंगे। पढ़ने के लिए धन्यवाद और आशा है कि आप अगले सप्ताह हमारे ब्लॉग पर मिलेंगे!

Leave a Comment